examples: move core examples into core/ folder; add triangle example

Signed-off-by: Stephen Gutekanst <stephen@hexops.com>

build.zig

@@ -558,13 +558,18 @@ fn buildExamples(
     };
 
     for ([_]struct {
+        core: bool = false,
         name: []const u8,
         deps: []const Dependency = &.{},
         wasm: bool = false,
         has_assets: bool = false,
     }{
+        // Mach core examples
+        .{ .core = true, .name = "custom-entrypoint", .deps = &.{} },
+        .{ .core = true, .name = "triangle", .deps = &.{} },
+
+        // Mach engine examples
         .{ .name = "hardware-check", .deps = &.{ .assets, .zigimg } },
-        .{ .name = "core-custom-entrypoint", .deps = &.{} },
         .{ .name = "custom-renderer", .deps = &.{} },
         .{ .name = "glyphs", .deps = &.{ .freetype, .assets } },
         .{ .name = "piano", .deps = &.{} },
@@ -574,8 +579,11 @@ fn buildExamples(
     }) |example| {
         if (target.result.cpu.arch == .wasm32 and !example.wasm) continue;
         const exe = b.addExecutable(.{
-            .name = example.name,
+            .name = if (example.core) b.fmt("core-{s}", .{example.name}) else example.name,
-            .root_source_file = .{ .path = b.fmt("examples/{s}/main.zig", .{example.name}) },
+            .root_source_file = if (example.core)
+                .{ .path = b.fmt("examples/core/{s}/main.zig", .{example.name}) }
+            else
+                .{ .path = b.fmt("examples/{s}/main.zig", .{example.name}) },
             .target = target,
             .optimize = optimize,
         });

examples/core/triangle/App.zig

@@ -0,0 +1,140 @@
+const std = @import("std");
+const mach = @import("mach");
+const gpu = mach.gpu;
+
+pub const name = .app;
+pub const Mod = mach.Mod(@This());
+
+pub const systems = .{
+    .init = .{ .handler = init },
+    .after_init = .{ .handler = afterInit },
+    .deinit = .{ .handler = deinit },
+    .tick = .{ .handler = tick },
+};
+
+title_timer: mach.Timer,
+pipeline: *gpu.RenderPipeline,
+
+pub fn deinit(core: *mach.Core.Mod, game: *Mod) void {
+    game.state().pipeline.release();
+    core.schedule(.deinit);
+}
+
+fn init(game: *Mod, core: *mach.Core.Mod) !void {
+    core.schedule(.init);
+    game.schedule(.after_init);
+}
+
+fn afterInit(game: *Mod, core: *mach.Core.Mod) !void {
+    // Create our shader module
+    const shader_module = core.state().device.createShaderModuleWGSL("shader.wgsl", @embedFile("shader.wgsl"));
+    defer shader_module.release();
+
+    // Blend state describes how rendered colors get blended
+    const blend = gpu.BlendState{};
+
+    // Color target describes e.g. the pixel format of the window we are rendering to.
+    const color_target = gpu.ColorTargetState{
+        .format = core.get(core.state().main_window, .framebuffer_format).?,
+        .blend = &blend,
+    };
+
+    // Fragment state describes which shader and entrypoint to use for rendering fragments.
+    const fragment = gpu.FragmentState.init(.{
+        .module = shader_module,
+        .entry_point = "frag_main",
+        .targets = &.{color_target},
+    });
+
+    // Create our render pipeline that will ultimately get pixels onto the screen.
+    const label = @tagName(name) ++ ".init";
+    const pipeline_descriptor = gpu.RenderPipeline.Descriptor{
+        .label = label,
+        .fragment = &fragment,
+        .vertex = gpu.VertexState{
+            .module = shader_module,
+            .entry_point = "vertex_main",
+        },
+    };
+    const pipeline = core.state().device.createRenderPipeline(&pipeline_descriptor);
+
+    // Store our render pipeline in our module's state, so we can access it later on.
+    game.init(.{
+        .title_timer = try mach.Timer.start(),
+        .pipeline = pipeline,
+    });
+    try updateWindowTitle(core);
+
+    core.schedule(.start);
+}
+
+fn tick(core: *mach.Core.Mod, game: *Mod) !void {
+    // TODO(important): event polling should occur in mach.Core module and get fired as ECS event.
+    // TODO(Core)
+    var iter = mach.core.pollEvents();
+    while (iter.next()) |event| {
+        switch (event) {
+            .close => core.schedule(.exit), // Tell mach.Core to exit the app
+            else => {},
+        }
+    }
+
+    // Grab the back buffer of the swapchain
+    // TODO(Core)
+    const back_buffer_view = mach.core.swap_chain.getCurrentTextureView().?;
+    defer back_buffer_view.release();
+
+    // Create a command encoder
+    const label = @tagName(name) ++ ".tick";
+    const encoder = core.state().device.createCommandEncoder(&.{ .label = label });
+    defer encoder.release();
+
+    // Begin render pass
+    const sky_blue_background = gpu.Color{ .r = 0.776, .g = 0.988, .b = 1, .a = 1 };
+    const color_attachments = [_]gpu.RenderPassColorAttachment{.{
+        .view = back_buffer_view,
+        .clear_value = sky_blue_background,
+        .load_op = .clear,
+        .store_op = .store,
+    }};
+    const render_pass = encoder.beginRenderPass(&gpu.RenderPassDescriptor.init(.{
+        .label = label,
+        .color_attachments = &color_attachments,
+    }));
+    defer render_pass.release();
+
+    // Draw
+    render_pass.setPipeline(game.state().pipeline);
+    render_pass.draw(3, 1, 0, 0);
+
+    // Finish render pass
+    render_pass.end();
+
+    // Submit our commands to the queue
+    var command = encoder.finish(&.{ .label = label });
+    defer command.release();
+    core.state().queue.submit(&[_]*gpu.CommandBuffer{command});
+
+    // Present the frame
+    core.schedule(.present_frame);
+
+    // update the window title every second
+    if (game.state().title_timer.read() >= 1.0) {
+        game.state().title_timer.reset();
+        try updateWindowTitle(core);
+    }
+}
+
+fn updateWindowTitle(core: *mach.Core.Mod) !void {
+    try mach.Core.printTitle(
+        core,
+        core.state().main_window,
+        "core-custom-entrypoint [ {d}fps ] [ Input {d}hz ]",
+        .{
+            // TODO(Core)
+            mach.core.frameRate(),
+            mach.core.inputRate(),
+        },
+    );
+    core.schedule(.update);
+}

examples/core/triangle/main.zig

@@ -0,0 +1,15 @@
+const mach = @import("mach");
+
+// The global list of Mach modules registered for use in our application.
+pub const modules = .{
+    mach.Core,
+    @import("App.zig"),
+};
+
+pub fn main() !void {
+    // Initialize mach.Core
+    try mach.core.initModule();
+
+    // Main loop
+    while (try mach.core.tick()) {}
+}

examples/core/triangle/shader.wgsl

@@ -0,0 +1,14 @@
+@vertex fn vertex_main(
+    @builtin(vertex_index) VertexIndex : u32
+) -> @builtin(position) vec4<f32> {
+    var pos = array<vec2<f32>, 3>(
+        vec2<f32>( 0.0,  0.5),
+        vec2<f32>(-0.5, -0.5),
+        vec2<f32>( 0.5, -0.5)
+    );
+    return vec4<f32>(pos[VertexIndex], 0.0, 1.0);
+}
+
+@fragment fn frag_main() -> @location(0) vec4<f32> {
+    return vec4<f32>(1.0, 0.0, 0.0, 1.0);
+}