284 lines
10 KiB
Zig
284 lines
10 KiB
Zig
// TODO(important): review all code in this file in-depth
|
|
const std = @import("std");
|
|
const zigimg = @import("zigimg");
|
|
const assets = @import("assets");
|
|
const mach = @import("mach");
|
|
const gpu = mach.gpu;
|
|
const gfx = mach.gfx;
|
|
const math = mach.math;
|
|
|
|
const vec2 = math.vec2;
|
|
const vec3 = math.vec3;
|
|
const Vec2 = math.Vec2;
|
|
const Vec3 = math.Vec3;
|
|
const Mat3x3 = math.Mat3x3;
|
|
const Mat4x4 = math.Mat4x4;
|
|
|
|
var gpa = std.heap.GeneralPurposeAllocator(.{}){};
|
|
|
|
timer: mach.Timer,
|
|
player: mach.EntityID,
|
|
direction: Vec2 = vec2(0, 0),
|
|
spawning: bool = false,
|
|
spawn_timer: mach.Timer,
|
|
fps_timer: mach.Timer,
|
|
frame_count: usize,
|
|
sprites: usize,
|
|
rand: std.rand.DefaultPrng,
|
|
time: f32,
|
|
allocator: std.mem.Allocator,
|
|
pipeline: mach.EntityID,
|
|
frame_encoder: *gpu.CommandEncoder = undefined,
|
|
frame_render_pass: *gpu.RenderPassEncoder = undefined,
|
|
|
|
// Define the globally unique name of our module. You can use any name here, but keep in mind no
|
|
// two modules in the program can have the same name.
|
|
pub const name = .game;
|
|
pub const Mod = mach.Mod(@This());
|
|
|
|
pub const global_events = .{
|
|
.init = .{ .handler = init },
|
|
.tick = .{ .handler = tick },
|
|
};
|
|
|
|
pub const local_events = .{
|
|
.end_frame = .{ .handler = endFrame },
|
|
};
|
|
|
|
fn init(
|
|
core: *mach.Core.Mod,
|
|
sprite: *gfx.Sprite.Mod,
|
|
sprite_pipeline: *gfx.SpritePipeline.Mod,
|
|
game: *Mod,
|
|
) !void {
|
|
// The Mach .core is where we set window options, etc.
|
|
mach.core.setTitle("gfx.Sprite example");
|
|
|
|
// We can create entities, and set components on them. Note that components live in a module
|
|
// namespace, e.g. the `.mach_gfx_sprite` module could have a 3D `.location` component with a different
|
|
// type than the `.physics2d` module's `.location` component if you desire.
|
|
|
|
// Create a sprite rendering pipeline
|
|
const allocator = gpa.allocator();
|
|
const pipeline = try core.newEntity();
|
|
try sprite_pipeline.set(pipeline, .texture, try loadTexture(core, allocator));
|
|
sprite_pipeline.send(.update, .{});
|
|
|
|
// Create our player sprite
|
|
const player = try core.newEntity();
|
|
try sprite.set(player, .transform, Mat4x4.translate(vec3(-0.02, 0, 0)));
|
|
try sprite.set(player, .size, vec2(32, 32));
|
|
try sprite.set(player, .uv_transform, Mat3x3.translate(vec2(0, 0)));
|
|
try sprite.set(player, .pipeline, pipeline);
|
|
sprite.send(.update, .{});
|
|
|
|
game.init(.{
|
|
.timer = try mach.Timer.start(),
|
|
.spawn_timer = try mach.Timer.start(),
|
|
.player = player,
|
|
.fps_timer = try mach.Timer.start(),
|
|
.frame_count = 0,
|
|
.sprites = 0,
|
|
.rand = std.rand.DefaultPrng.init(1337),
|
|
.time = 0,
|
|
.allocator = allocator,
|
|
.pipeline = pipeline,
|
|
});
|
|
}
|
|
|
|
fn tick(
|
|
core: *mach.Core.Mod,
|
|
sprite: *gfx.Sprite.Mod,
|
|
sprite_pipeline: *gfx.SpritePipeline.Mod,
|
|
game: *Mod,
|
|
) !void {
|
|
// TODO(important): event polling should occur in mach.Core module and get fired as ECS events.
|
|
var iter = mach.core.pollEvents();
|
|
var direction = game.state().direction;
|
|
var spawning = game.state().spawning;
|
|
while (iter.next()) |event| {
|
|
switch (event) {
|
|
.key_press => |ev| {
|
|
switch (ev.key) {
|
|
.left => direction.v[0] -= 1,
|
|
.right => direction.v[0] += 1,
|
|
.up => direction.v[1] += 1,
|
|
.down => direction.v[1] -= 1,
|
|
.space => spawning = true,
|
|
else => {},
|
|
}
|
|
},
|
|
.key_release => |ev| {
|
|
switch (ev.key) {
|
|
.left => direction.v[0] += 1,
|
|
.right => direction.v[0] -= 1,
|
|
.up => direction.v[1] -= 1,
|
|
.down => direction.v[1] += 1,
|
|
.space => spawning = false,
|
|
else => {},
|
|
}
|
|
},
|
|
.close => core.send(.exit, .{}),
|
|
else => {},
|
|
}
|
|
}
|
|
game.state().direction = direction;
|
|
game.state().spawning = spawning;
|
|
|
|
var player_transform = sprite.get(game.state().player, .transform).?;
|
|
var player_pos = player_transform.translation();
|
|
if (spawning and game.state().spawn_timer.read() > 1.0 / 60.0) {
|
|
// Spawn new entities
|
|
_ = game.state().spawn_timer.lap();
|
|
for (0..100) |_| {
|
|
var new_pos = player_pos;
|
|
new_pos.v[0] += game.state().rand.random().floatNorm(f32) * 25;
|
|
new_pos.v[1] += game.state().rand.random().floatNorm(f32) * 25;
|
|
|
|
const new_entity = try core.newEntity();
|
|
try sprite.set(new_entity, .transform, Mat4x4.translate(new_pos).mul(&Mat4x4.scale(Vec3.splat(0.3))));
|
|
try sprite.set(new_entity, .size, vec2(32, 32));
|
|
try sprite.set(new_entity, .uv_transform, Mat3x3.translate(vec2(0, 0)));
|
|
try sprite.set(new_entity, .pipeline, game.state().pipeline);
|
|
game.state().sprites += 1;
|
|
}
|
|
}
|
|
|
|
// Multiply by delta_time to ensure that movement is the same speed regardless of the frame rate.
|
|
const delta_time = game.state().timer.lap();
|
|
|
|
// Rotate entities
|
|
var archetypes_iter = core.entities.query(.{ .all = &.{
|
|
.{ .mach_gfx_sprite = &.{.transform} },
|
|
} });
|
|
while (archetypes_iter.next()) |archetype| {
|
|
const ids = archetype.slice(.entity, .id);
|
|
const transforms = archetype.slice(.mach_gfx_sprite, .transform);
|
|
for (ids, transforms) |id, *old_transform| {
|
|
_ = id;
|
|
const location = old_transform.*.translation();
|
|
// var transform = old_transform.mul(&Mat4x4.translate(-location));
|
|
// transform = mat.rotateZ(0.3 * delta_time).mul(&transform);
|
|
// transform = transform.mul(&Mat4x4.translate(location));
|
|
var transform = Mat4x4.ident;
|
|
transform = transform.mul(&Mat4x4.translate(location));
|
|
transform = transform.mul(&Mat4x4.rotateZ(2 * math.pi * game.state().time));
|
|
transform = transform.mul(&Mat4x4.scaleScalar(@min(math.cos(game.state().time / 2.0), 0.5)));
|
|
|
|
// TODO: .set() API is substantially slower due to internals
|
|
// try sprite.set(id, .transform, transform);
|
|
old_transform.* = transform;
|
|
}
|
|
}
|
|
|
|
// Calculate the player position, by moving in the direction the player wants to go
|
|
// by the speed amount.
|
|
const speed = 200.0;
|
|
player_pos.v[0] += direction.x() * speed * delta_time;
|
|
player_pos.v[1] += direction.y() * speed * delta_time;
|
|
try sprite.set(game.state().player, .transform, Mat4x4.translate(player_pos));
|
|
sprite.send(.update, .{});
|
|
|
|
// Perform pre-render work
|
|
sprite_pipeline.send(.pre_render, .{});
|
|
|
|
// Create a command encoder for this frame
|
|
const label = @tagName(name) ++ ".tick";
|
|
game.state().frame_encoder = core.state().device.createCommandEncoder(&.{ .label = label });
|
|
|
|
// Grab the back buffer of the swapchain
|
|
const back_buffer_view = mach.core.swap_chain.getCurrentTextureView().?;
|
|
defer back_buffer_view.release();
|
|
|
|
// Begin render pass
|
|
const sky_blue = gpu.Color{ .r = 0.776, .g = 0.988, .b = 1, .a = 1 };
|
|
const color_attachments = [_]gpu.RenderPassColorAttachment{.{
|
|
.view = back_buffer_view,
|
|
.clear_value = sky_blue,
|
|
.load_op = .clear,
|
|
.store_op = .store,
|
|
}};
|
|
// TODO: can we eliminate this assignment
|
|
game.state().frame_encoder = core.state().device.createCommandEncoder(&.{ .label = label });
|
|
game.state().frame_render_pass = game.state().frame_encoder.beginRenderPass(&gpu.RenderPassDescriptor.init(.{
|
|
.label = label,
|
|
.color_attachments = &color_attachments,
|
|
}));
|
|
|
|
// Render our sprite batch
|
|
sprite_pipeline.state().render_pass = game.state().frame_render_pass;
|
|
sprite_pipeline.send(.render, .{});
|
|
|
|
// Finish the frame once rendering is done.
|
|
game.send(.end_frame, .{});
|
|
|
|
game.state().time += delta_time;
|
|
}
|
|
|
|
fn endFrame(game: *Mod) !void {
|
|
// Finish render pass
|
|
game.state().frame_render_pass.end();
|
|
const label = @tagName(name) ++ ".endFrame";
|
|
var command = game.state().frame_encoder.finish(&.{ .label = label });
|
|
game.state().frame_encoder.release();
|
|
defer command.release();
|
|
mach.core.queue.submit(&[_]*gpu.CommandBuffer{command});
|
|
|
|
// Present the frame
|
|
mach.core.swap_chain.present();
|
|
|
|
// Every second, update the window title with the FPS
|
|
if (game.state().fps_timer.read() >= 1.0) {
|
|
try mach.core.printTitle("gfx.Sprite example [ FPS: {d} ] [ Sprites: {d} ]", .{ game.state().frame_count, game.state().sprites });
|
|
game.state().fps_timer.reset();
|
|
game.state().frame_count = 0;
|
|
}
|
|
game.state().frame_count += 1;
|
|
}
|
|
|
|
// TODO: move this helper into gfx module
|
|
fn loadTexture(core: *mach.Core.Mod, allocator: std.mem.Allocator) !*gpu.Texture {
|
|
const device = core.state().device;
|
|
const queue = device.getQueue();
|
|
|
|
// Load the image from memory
|
|
var img = try zigimg.Image.fromMemory(allocator, assets.sprites_sheet_png);
|
|
defer img.deinit();
|
|
const img_size = gpu.Extent3D{ .width = @as(u32, @intCast(img.width)), .height = @as(u32, @intCast(img.height)) };
|
|
|
|
// Create a GPU texture
|
|
const label = @tagName(name) ++ ".loadTexture";
|
|
const texture = device.createTexture(&.{
|
|
.label = label,
|
|
.size = img_size,
|
|
.format = .rgba8_unorm,
|
|
.usage = .{
|
|
.texture_binding = true,
|
|
.copy_dst = true,
|
|
.render_attachment = true,
|
|
},
|
|
});
|
|
const data_layout = gpu.Texture.DataLayout{
|
|
.bytes_per_row = @as(u32, @intCast(img.width * 4)),
|
|
.rows_per_image = @as(u32, @intCast(img.height)),
|
|
};
|
|
switch (img.pixels) {
|
|
.rgba32 => |pixels| queue.writeTexture(&.{ .texture = texture }, &data_layout, &img_size, pixels),
|
|
.rgb24 => |pixels| {
|
|
const data = try rgb24ToRgba32(allocator, pixels);
|
|
defer data.deinit(allocator);
|
|
queue.writeTexture(&.{ .texture = texture }, &data_layout, &img_size, data.rgba32);
|
|
},
|
|
else => @panic("unsupported image color format"),
|
|
}
|
|
return texture;
|
|
}
|
|
|
|
fn rgb24ToRgba32(allocator: std.mem.Allocator, in: []zigimg.color.Rgb24) !zigimg.color.PixelStorage {
|
|
const out = try zigimg.color.PixelStorage.init(allocator, .rgba32, in.len);
|
|
var i: usize = 0;
|
|
while (i < in.len) : (i += 1) {
|
|
out.rgba32[i] = zigimg.color.Rgba32{ .r = in[i].r, .g = in[i].g, .b = in[i].b, .a = 255 };
|
|
}
|
|
return out;
|
|
}
|